affection/src/Affection/Util.hs

module Affection.Util where

import Affection.Types
import Affection.Logging
import Affection.MessageBus.Message.WindowMessage

import SDL (($=))
import qualified SDL
import qualified Graphics.Rendering.OpenGL as GL

import System.Clock

import Control.Monad.State

-- | Prehandle SDL events
preHandleEvents :: [SDL.Event] -> Affection us [SDL.EventPayload]
preHandleEvents evs =
  return $ map SDL.eventPayload evs

-- | Return the userstate to the user
getAffection :: Affection us us
getAffection = gets userState

-- | Put altered user state back
putAffection
  :: us              -- User state
  -> Affection us ()
putAffection us = do
  ad <- get
  put $ ad
    { userState = us }

-- | block a thread for a specified amount of time
delaySec
  :: Int -- ^ Number of seconds
  -> IO ()
delaySec dur = SDL.delay (fromIntegral $ dur * 1000)

-- | Get time since start but always the same in the current tick.
getElapsedTime :: Affection us Double
getElapsedTime = gets elapsedTime

-- | Get delta time (time elapsed from last frame)
getDelta :: Affection us Double
getDelta = gets deltaTime

-- | Quit the engine loop
quit :: Affection us ()
quit = do
  ad <- get
  put $ ad { quitEvent = True }

-- | Toggle the Screen mode between 'SDL.Windowed' and 'SDL.FullscreenDesktop'.
-- Pauses the Engine in the process.
toggleScreen :: Affection us ()
toggleScreen = do
  ad <- get
  newMode <- case screenMode ad of
    SDL.Windowed -> do
      SDL.setWindowMode (drawWindow ad) SDL.FullscreenDesktop
      return SDL.FullscreenDesktop
    SDL.FullscreenDesktop -> do
      SDL.setWindowMode (drawWindow ad) SDL.Windowed
      return SDL.Windowed
    x -> do
      liftIO $ logIO Warn ("Unexpected Screen mode: " ++ show x)
      return x
  now <- liftIO $ getTime Monotonic
  put ad
    { sysTime = now
    , screenMode = newMode
    }

-- | Fit the GL Viewport to Window size
fitViewport
  :: Double               -- ^ Image Ratio (width / height)
  -> WindowMessage        -- ^ Incoming Message. Listens only on
                          -- 'MsgWindowResize' and ignores all others.
  -> Affection us ()
fitViewport ratio (MsgWindowResize _ _ (SDL.V2 w h)) = do
  liftIO $ logIO Verbose "Fitting Viewport to size"
  if (fromIntegral w / fromIntegral h) > ratio
  then do
    let nw = floor (fromIntegral h * ratio)
        dw = floor ((fromIntegral w - fromIntegral nw) / 2 :: Double)
    GL.viewport $= (GL.Position dw 0, GL.Size nw h)
  else do
    let nh = floor (fromIntegral w / ratio)
        dh = floor ((fromIntegral h - fromIntegral nh) / 2 :: Double)
    GL.viewport $= (GL.Position 0 dh, GL.Size w nh)
fitViewport _ _ = return ()